SWI-Prolog -- library(quasi_quotations): Define Quasi Quotation syntax

A.44 library(quasi_quotations): Define Quasi Quotation syntax

author

Jan Wielemaker. Introduction of Quasi Quotation was suggested by Michael Hendricks.

Inspired by Haskell, SWI-Prolog support quasi quotation. Quasi quotation allows for embedding (long) strings using the syntax of an external language (e.g., HTML, SQL) in Prolog text and syntax-aware embedding of Prolog variables in this syntax. At the same time, quasi quotation provides an alternative to represent long strings and atoms in Prolog.

The basic form of a quasi quotation is defined below. Here, Syntax is an arbitrary Prolog term that must parse into a callable (atom or compound) term and Quotation is an arbitrary sequence of characters, not including the sequence |}. If this sequence needs to be embedded, it must be escaped according to the rules of the target language or the‘quoter’must provide an escaping mechanism.

{|Syntax||Quotation|}

While reading a Prolog term, and if the Prolog flag quasi_quotes is set to true (which is the case if this library is loaded), the parser collects quasi quotations. After reading the final full stop, the parser makes the call below. Here, SyntaxName is the functor name of Syntax above and SyntaxArgs is a list holding the arguments, i.e., Syntax =.. [SyntaxName|SyntaxArgs]. Splitting the syntax into its name and arguments is done to make the quasi quotation parser a predicate with a consistent arity 4, regardless of the number of additional arguments.

call(+SyntaxName, +Content, +SyntaxArgs, +VariableNames, -Result)

The arguments are defined as

SyntaxName is the principal functor of the quasi quotation syntax. This must be declared using quasi_quotation_syntax/1 and there must be a predicate SyntaxName/4.

Content is an opaque term that carries the content of the quasi quoted material and position information about the source code. It is passed to with_quasi_quote_input/3.

SyntaxArgs carries the additional arguments of the Syntax. These are commonly used to make the parameter passing between the clause and the quasi quotation explicit. For example:

    ...,
    {|html(Name, Address)||
     <tr><td>Name<td>Address</tr>
     |}

VariableNames is the complete variable dictionary of the clause as it is made available throug read_term/3 with the option variable_names. It is a list of terms Name = Var.

Result is a variable that must be unified to resulting term. Typically, this term is structured Prolog tree that carries a (partial) representation of the abstract syntax tree with embedded variables that pass the Prolog parameters. This term is normally either passed to a predicate that serializes the abstract syntax tree, or a predicate that processes the result in Prolog. For example, HTML is commonly embedded for writing HTML documents (see library(http/html_write)). Examples of languages that may be embedded for processing in Prolog are SPARQL, RuleML or regular expressions.

The file library(http/html_quasiquotations) provides the, suprisingly simple, quasi quotation parser for HTML.

[det]with_quasi_quotation_input(+Content, -Stream, :Goal)

Process the quasi-quoted Content using Stream parsed by Goal. Stream is a temporary stream with the following properties:

Its initial position represents the position of the start of the quoted material.
It is a text stream, using utf8 encoding.
It allows for repositioning
It will be closed after Goal completes.

Goal is executed as once(Goal). Goal must succeed. Failure or exceptions from Goal are interpreted as syntax errors.

See also: phrase_from_quasi_quotation/2 can be used to process a quotation using a grammar.

[det]phrase_from_quasi_quotation(:Grammar, +Content)

Process the quasi quotation using the DCG Grammar. Failure of the grammar is interpreted as a syntax error.

See also: with_quasi_quotation_input/3 for processing quotations from stream.

[det]quasi_quotation_syntax(:SyntaxName)

Declare the predicate SyntaxName/4 to implement the the quasi quote syntax SyntaxName. Normally used as a directive.

quasi_quotation_syntax_error(+Error)

Report syntax_error(Error) using the current location in the quasi quoted input parser.

throws: error(syntax_error(Error), Position)

Anne Ogborn said (2015-10-06T02:59:55):

Here's another example.

This one puts out the usual SWI-Prolog SGML/XML representation of an HTMl DIV if the quasiquoted content is all whitespace it says empty, if it contains foo then the next letter should match a variable name in the argument list, and the value of that variable will be inserted in the output.

If foo isn't present, the value of the first variable will be reported. Both Vars and Dict are needed in case the argument isn't a variable (as in second test case).


:- module(jetpack, [jet/4]).

:- use_module(library(dcg/basics)).
:- use_module(library(quasi_quotations)).

% so we recognize {|jet(X)||.... |}
:- quasi_quotation_syntax(jet).

%!	jet_syntax(+Vars:list, +Dict:list, -DOM:list) is det
%
%	called at compile time to convert the quasiquote to
%	the target language
%
%	We make ourselves look like the html quoter
%	so you can insert jet in the content fed to html//1
%	or {|html(X)||<p>some html with X</p>|}
%
jet_syntax(_Vars, _Dict, [element(div, [], ['empty'])]) -->
      blanks,
      eos.
jet_syntax(_, Dict, [element(div, [], ['has foo, matching var is', V])]) -->
      string(_),
      "foo",
      [VarName],
      {
          atom_codes(AtomName, [VarName]),
          member(AtomName=V, Dict)
      },
      string(_),
      eos,
      !.
jet_syntax([VH|_], _Dict, [element(div, [], ['no foo, first var is', VH])]) -->
      string(_),
      eos.

% actually does the conversion, jet_syntax does the heavy lifting
jet(Content, Vars, Dict, DOM) :-
      phrase_from_quasi_quotation(jet_syntax(Vars, Dict, DOM), Content).


testjet :-
      X=7,
      Y={|jet(X)|| fooX |},
      writeln(Y),
      Z = {|jet(7)|| oogle |},
      writeln(Z).



results

[debug]  ?- testjet.
Correct to: "jetpack:testjet"? yes
[element(div,[],[has foo, matching var is,7])]
[element(div,[],[no foo, first var is,7])]
true.

Props to Carlo, I started with his example.

Carlo Capelli said (2014-09-17T14:40:49):

Maybe I'm missing the relevant bits or docs, but the simplest use case - long atoms - required to me some effort to be devised. So, for other newbies out there, here is the code I wrote to interface ODBC:

:- use_module(library(quasi_quotations)).
:- quasi_quotation_syntax(odbc).

copy_([]) --> [].
copy_([C|Cs]) --> [C], copy_(Cs).
copy(A) --> copy_(Cs), {atom_codes(A, Cs)}.

odbc(Content, _Vars, _Dict, DOM) :-
        phrase_from_quasi_quotation(copy(DOM), Content).

and now we can write cleaner code. For instance, reading from OpenCart data model

test_qq_odbc :-
        myodbc_connect_db(Conn),
        odbc_query(Conn, {|odbc||
select
 P.image,D.description,D.meta_keywords,C.image,G.description
from
 product P, product_description D, category C, category_description G, product_to_category J
where
 P.product_id=D.product_id and
 P.product_id=J.product_id and C.category_id=J.category_id and
 C.category_id=G.category_id
        |}, Row),
        writeln(Row).

Peter Ludemann said (2021-03-02T20:16:57):

The code for HTML quasi-quotations is here: https://github.com/SWI-Prolog/packages-http/blob/master/html_quasiquotations.pl (which is loaded by library(http/html_write).

LogicalCaptain said (2020-10-16T11:13:29):

File under "docs need help"

_"SyntaxName is the principal functor of the quasi quotation syntax."_

Shouldn't that be _"SyntaxName is the functor name of the 'Syntax' callable term"_.

The links for the libraries mentioned:

library(http/html_write) : https://eu.swi-prolog.org/pldoc/doc/_SWI_/library/http/html_write.pl

library(http/html_quasiquotations) : https://eu.swi-prolog.org/pldoc/doc/_SWI_/library/http/html_quasiquotations.pl

I didn't find the above neither through the content menu nor through the search box, but only through Google.