Did you know ... Search Documentation:
Predicate read_line_to_string/2
Availability::- use_module(library(readutil)).(can be autoloaded)
Source[det]read_line_to_string(+Stream, -String)
Read the next line from Stream into String. String does not contain the line terminator. String is unified with the atom end_of_file if the end of the file is reached.
See also
read_string/5 can be used to read lines with separated records without creating intermediate strings.

Examples

Backtrack over lines in a file

Backtrack over lines in a file

file_line(File, Line) :-
    setup_call_cleanup(open(File, read, In),
        stream_line(In, Line),
        close(In)).

stream_line(In, Line) :-
    repeat,
    (   read_line_to_string(In, Line0),
        Line0 \== end_of_file
    ->  Line0 = Line
    ;   !,
        fail
    ).

This will backtrack over consecutive lines in the input. If we use the Unix dictionary words:

?- file_line("/usr/share/dict/words", Word).
Word = "A" ;
Word = "a" ;
Word = "aa" ;
Word = "aal" ; % and so on

This doesn't load all lines to memory, so it can be used with very large files.

See also
- read_line_to_codes/2 to read to a code list instead of a string
- read_string/5 for more control over the separator and stripping
Tags are associated to your profile if you are logged in
Tags:
LogicalCaptain said (2021-03-10T07:26:08):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

See also

Example

Can be used to ask the user as a proper replacement for read/1

ask_user :-
   format("You must answer 'yes' to accept this offer one cannot refuse!~n"),
   read_line_to_string(user_input,S1),
   string_lower(S1,S2),
   (
      member(S2,["yes","1","ok","y","ja","oui"])
      -> format("You may proceed, good citizen.~n")
      ;  format("I am sorry to hear that.~n"), fail
   ).

Then:

?- ask_user.
You must answer 'yes' to accept this offer one cannot refuse!
|: yes
You may proceed, good citizen.
true.