Did you know ... Search Documentation:
Predicate !/0
Availability:built-in
[ISO]!
Cut. Discard all choice points created since entering the predicate in which the cut appears. In other words, commit to the clause in which the cut appears and discard choice points that have been created by goals to the left of the cut in the current clause. Meta calling is opaque to the cut. This implies that cuts that appear in a term that is subject to meta-calling (call/1) only affect choice points created by the meta-called term. The following control structures are transparent to the cut: ;/2, ->/2 and *->/2. Cuts appearing in the condition part of ->/2 and *->/2 are opaque to the cut. The table below explains the scope of the cut with examples. Prunes here means “prunes X choice point created by X” .

t0 :- (a, !, b). % prunes a/0 and t0/0
t1 :- (a, !, fail ; b). % prunes a/0 and t1/0
t2 :- (a -> b, ! ; c). % prunes b/0 and t2/0
t3 :- (a, !, b -> c ; d). % prunes a/0
t4 :- call((a, !, fail ; b)). % prunes a/0
t5 :- \+(a, !, fail). % prunes a/0

Examples

Normally used to update the value associated with a key. For example, if the value is a count that must be incremented, do

inc_count(Key, A0, A) :-
     get_assoc(Key, A0, C0, A, C), !,
     C is C0+1.
inc_count(Key, A0, A) :-
     put_assoc(Key, A0, 1, A).
Backtrack over lines in a file

Backtrack over lines in a file

file_line(File, Line) :-
    setup_call_cleanup(open(File, read, In),
        stream_line(In, Line),
        close(In)).

stream_line(In, Line) :-
    repeat,
    (   read_line_to_string(In, Line0),
        Line0 \== end_of_file
    ->  Line0 = Line
    ;   !,
        fail
    ).

This will backtrack over consecutive lines in the input. If we use the Unix dictionary words:

?- file_line("/usr/share/dict/words", Word).
Word = "A" ;
Word = "a" ;
Word = "aa" ;
Word = "aal" ; % and so on

This doesn't load all lines to memory, so it can be used with very large files.

See also
- read_line_to_codes/2 to read to a code list instead of a string
- read_string/5 for more control over the separator and stripping
Use append/3 for substitution in a list

Use append/3 for substitution in a list

The append/3 predicate can be used to split and join lists. We can combine that to realise substituting all appearances of a sublist into another as illustrated below.

  • append(This, After, Rest) creates a pattern from This, i.e., the list Rest starts with This.
  • append(Before, Rest, MyStr) matches the pattern against the input list. On a match we commit (!). Now Before is the input list before the match and After is the input list after the match.
  • Recursively replace in After
  • Join the parts.
subst(This, That, MyStr, Result) :-
    append(This, After, Rest),
    append(Before, Rest, MyStr),
    !,
    subst(This, That, After, AfterResult),
    append([Before,That,AfterResult], Result).
subst(_, _, S, S).
?- portray_text(true).
true.

?- subst(`this`,`that`,`athishellothis`,R).
R = `athathellothat`.
Tags are associated to your profile if you are logged in|Report abuse
Tags:
  • cut
  • doc-needs-help
LogicalCaptain said (2020-11-04T20:09:27):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

Doc-needs-help

The expression

t4 :- \+(a, !, fail).

is invalid. There must be a space after \+ or double parentheses must be used.

Extended examples

a(a0).
a(a1).
a(a2).
b(b0).
b(b1).
b(b2).
c(c0).
c(c1).
c(c2).

% parentheses added for clarity below

t0(A,B)   :- a(A),!,b(B).
t0(x,x).

t1(A,B)   :- (a(A),!,fail);b(B).
t1(x,x).

t2(A,B,C) :- (a(A) -> (b(B),!)) ; c(C).
t2(x,x,x).

t3(A,B)   :- call(((a(A),!,fail);b(B))).
t3(x,x).

t4(A)     :- \+ (a(A),!,fail).     % there must be a space after \+
t4_bis(A) :- \+((a(A),!,fail)).    % ... or use double parentheses

% Bonus round

d1(A,B)   :- call((a(A),!,b(B))).  % ! is part of the called goal

d2(X)     :- a(X);!;b(X);c(X).     % actually 4 clauses, one of which is d2(X) :- !,true.

d3(X)     :- a(X);(b(X),!);c(X).   % actually 3 clauses, one of which is d3(X) :- b(X),!,true.

Use write_canonical/1 to print a term lacking in parentheses if you are unsure about parenthization. The term will be printed in prefix order. For example:

?- write_canonical(((a(A), !, fail ; b(B)))).
;(','(a(_),','(!,fail)),b(_))

And thus:

?- findall([A,B],t0(A,B),Found).
Found = [[a0, b0], [a0, b1], [a0, b2]].
?- findall([A,B],t1(A,B),Found).
Found = [].
?- findall([A,B,C],t2(A,B,C),Found).
Found = [[a0, b0, _8678]].
?- findall([A,B],t3(A,B),Found).
Found = [[x, x]].
?- findall([A],t4(A),Found). % binding of A is not retained outside of \+
Found = [[_6518]].

?- findall([A],t4_bis(A),Found).
Found = [[_6324]].
?- findall([A,B],d1(A,B),Found).
Found = [[a0, b0], [a0, b1], [a0, b2]].
?- findall([X],d2(X),Found).
Found = [[a0], [a1], [a2], [_9990]].
?- findall([X],d3(X),Found).
Found = [[a0], [a1], [a2], [b0]].

Hacker's corner

prolog_cut_to/1