1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2003-2024, University of Amsterdam
    7                              VU University Amsterdam
    8                              CWI, Amsterdam
    9                              SWI-Prolog Solutions b.v.
   10    All rights reserved.
   11
   12    Redistribution and use in source and binary forms, with or without
   13    modification, are permitted provided that the following conditions
   14    are met:
   15
   16    1. Redistributions of source code must retain the above copyright
   17       notice, this list of conditions and the following disclaimer.
   18
   19    2. Redistributions in binary form must reproduce the above copyright
   20       notice, this list of conditions and the following disclaimer in
   21       the documentation and/or other materials provided with the
   22       distribution.
   23
   24    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   25    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   26    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   27    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   28    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   29    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   30    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   31    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   32    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   33    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   34    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   35    POSSIBILITY OF SUCH DAMAGE.
   36*/
   37
   38:- module(make,
   39          [ make/0,
   40            make_reload_file/1      % +File
   41          ]).   42:- autoload(library(apply),[maplist/2]).   43:- autoload(library(check),[list_undefined/0,list_void_declarations/0]).   44:- use_module(library(debug),[debug/3]).   45:- autoload(library(lists),[list_to_set/2,member/2]).   46:- autoload(library(option),[merge_options/3]).   47
   48
   49:- set_prolog_flag(generate_debug_info, false).   50
   51/** <module>  Reload modified source files
   52
   53This module provides the SWI-Prolog   `make'  facility that synchronises
   54Prolog internal database after loaded files have been edited.
   55
   56@bug    Dependency tracking is incomplete.  Notably, there is no
   57        dependency tracking if compilation of one module depends
   58        on goal_expansion/2 or term_expansion/2 rules provided by
   59        another.
   60*/
   61
   62:- multifile
   63    prolog:make_hook/2.   64
   65
   66%!  make
   67%
   68%   Reload all source files that have   been changed since they were
   69%   loaded. This predicate peforms the following steps:
   70%
   71%     1. Compute the set of files that need to be reloaded.
   72%     2. Call the hook prolog:make_hook(before, Files)
   73%     3. Reload the files
   74%     4. Call the hook prolog:make_hook(after, Files)
   75%     5. If (4) fails, call list_undefined/0.
   76%
   77%   The hooks are called  with  an  empty   list  if  no  files need
   78%   reloading.
   79
   80make :-
   81    notrace(make_no_trace).
   82
   83make_no_trace :-
   84    '$update_library_index'([]),
   85    findall(File, modified_file(File), Reload0),
   86    list_to_set(Reload0, Reload),
   87    (   prolog:make_hook(before, Reload)
   88    ->  true
   89    ;   true
   90    ),
   91    print_message(silent, make(reload(Reload))),
   92    maplist(make_reload_file, Reload),
   93    print_message(silent, make(done(Reload))),
   94    (   prolog:make_hook(after, Reload)
   95    ->  true
   96    ;   list_undefined,
   97        list_void_declarations
   98    ).
   99
  100%!  modified_file(-File) is nondet.
  101%
  102%   True when File is modified after it has been loaded.
  103%
  104%   (*) A file is considered modified if   the  modification time of the
  105%   file is at least 1ms later that when  it was loaded. The 1ms relaxed
  106%   matching is used to compensate for   inconsistent float handling and
  107%   possible timing jitter.
  108%
  109%   @see https://github.com/SWI-Prolog/swipl-devel/issues/303
  110
  111modified_file(File) :-
  112    source_file_property(Source, modified(Time)),
  113    \+ source_file_property(Source, included_in(_,_)),
  114    Time > 0.0,                     % See source_file/1
  115    (   source_file_property(Source, derived_from(File, LoadTime))
  116    ->  true
  117    ;   File = Source,
  118        LoadTime = Time
  119    ),
  120    (   catch(time_file(File, Modified), _, fail),
  121        Modified - LoadTime > 0.001             % (*)
  122    ->  true
  123    ;   file_includes(Source, Included, IncLoadTime, [Source]),
  124        catch(time_file(Included, Modified), _, fail),
  125        Modified - IncLoadTime > 0.001          % (*)
  126    ->  true
  127    ).
  128
  129file_includes(Source, Included, IncLoadTime, Seen) :-
  130    source_file_property(Source, includes(Included0, IncLoadTime0)),
  131    \+ memberchk(Included0, Seen),
  132    (   Included = Included0,
  133        IncLoadTime = IncLoadTime0
  134    ;   file_includes(Included0, Included, IncLoadTime, [Included0|Seen])
  135    ).
  136
  137%!  make_reload_file(File)
  138%
  139%   Reload file into the proper module.
  140%
  141%   @bug    If modules import each other, we must load them in the
  142%           proper order for import/export dependencies.
  143
  144:- public reload_file/1.                % Used by PDT
  145reload_file(File) :- make_reload_file(File).
  146
  147make_reload_file(File) :-
  148    source_base_name(File, Compile),
  149    findall(M-Opts,
  150            source_file_property(File, load_context(M, _, Opts)),
  151            Modules),
  152    (   Modules = [First-OptsFirst|Rest]
  153    ->  Extra = [ silent(false),
  154                  register(false)
  155                ],
  156        merge_options([if(true)|Extra], OptsFirst, OFirst),
  157        debug(make, 'Make: First load ~q', [load_files(First:Compile, OFirst)]),
  158        load_files(First:Compile, OFirst),
  159        forall(member(Context-Opts, Rest),
  160               ( merge_options([if(not_loaded)|Extra], Opts, O),
  161                 debug(make, 'Make: re-import: ~q',
  162                       [load_files(Context:Compile, O)]),
  163                 load_files(Context:Compile, O)
  164               ))
  165    ;   load_files(user:Compile)
  166    ).
  167
  168source_base_name(File, Compile) :-
  169    file_name_extension(Compile, Ext, File),
  170    user:prolog_file_type(Ext, prolog),
  171    !.
  172source_base_name(File, File).
  173
  174
  175%!  prolog:make_hook(+When, +Files) is semidet.
  176%
  177%   This hook is called by make/0. It   is called with the following
  178%   values for When:
  179%
  180%     - before
  181%     The hook is called before reloading starts. The default
  182%     action is to do nothing.
  183%
  184%     - after
  185%     The hook is called after reloading completed.  The default
  186%     action is to call list_undefined/1 as:
  187%
  188%       ==
  189%       list_undefined([scan(local)]).
  190%       ==
  191%
  192%   The hook can be  used  to   change  program  validation, stop or
  193%   restart services, etc.
  194%
  195%   @arg Files is a list holding the canonical file names of the
  196%        files that need to be reloaded.  This list can be empty.